Kopiëren tussen werkboeken met verschillende namen

stemmen
0

Ik probeer van de ene geopende werkmap te kopiëren / plakken waarden naar de andere. Geen van de werkboeken statische namen hebben, dus er zal geen naam consistentie. Zowel van mijn werkboeken zal open zijn en zullen de enige geopende bestanden.

Kan iemand me helpen dit op te lossen code om te werken als ik niet de bestandsnamen weten?

Range(M7:R19).Select
Selection.Copy
Windows(new template.xlsm).Activate
Range(M7).Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
    :=False, Transpose:=False
Windows(old template.xlsm).Activate
Range(S7:AT16).Select
Application.CutCopyMode = False
Selection.Copy
Windows(new template.xlsm).Activate
Range(U7).Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
    :=False, Transpose:=False
De vraag is gesteld op 13/01/2020 om 23:58
bron van user
In andere talen...                            


2 antwoorden

stemmen
1

Je moet twee creëren Workbookvariabelen, om distinquish tussen degene die u wilt kopiëren van en waar u wilt plakken aan . Dus iets om mee te beginnen zou zijn (omdat dit de enige twee werkmappen openen run-time):

Sub Test()

Dim ws As Workbook, wbCopy As Workbook, wsPaste As Workbook

For Each wb In Application.Workbooks
    If IsNumeric(Right(wb.Name, 1)) Then
        Set wbCopy = wb
    Else
        Set wbPaste = wb
    End If
Next wb

'Continue coding... Below is just an option:
wbPaste.Worksheets(1).Range("U7:AV16").Value = wbCopy.Worksheets(1).Range("S7:AT16").Value
'Same thing for other ranges....  

End Sub

Het tweede deel van de code is voor u te overwegen. Ik weet niet welke blad dat u verwijzen naar op beide werkboek, noch ik weten of je echt nodig hebt om te kopiëren / plakken te doen. In mijn voorbeeld ben ik met de Worksheetmet de index 1en ik uitgegaan van een eenvoudige Valueoverdracht kan worden wat je eigenlijk wilt.

Maar deze laatste twee dingen voor u te overwegen.

antwoordde op 14/01/2020 om 00:23
bron van user

stemmen
1

Alternatieve methode door gebruik Likeoperator om te testen voor de bron / bestemming werkboeken. Biedt ook een manier om de bron / bestemming te bereiken die door middel kan worden doorgelust voor het gemak van het debuggen en later updaten definiëren. Code veel commentaar voor de duidelijkheid.

Sub tgr()

    Dim wb As Workbook
    Dim wsSource As Worksheet
    Dim wsDest As Worksheet

    'Check if exactly 2 workbooks are currently open
    If Application.Workbooks.Count <> 2 Then
        MsgBox "ERROR - There are [" & Application.Workbooks.Count & "] workbooks open." & Chr(10) & _
               "There must be two workbooks open:" & Chr(10) & _
               "-The source workbook (old template)" & Chr(10) & _
               "-The destination workbook"
        Exit Sub
    End If

    For Each wb In Application.Workbooks
        If wb.Name Like "*#.xls?" Then
            'Workbook name ends in number(s), this is the source workbook that will be copied from
            'You'll need to specify which sheet you're working with, this example code assumes the activesheet of that workbook
            Set wsSource = wb.ActiveSheet
        Else
            'Workbook name does not end in number(s), this is the source workbook that will be pasted to
            'You'll need to specify which sheet you're working with, this example code assumes the activesheet of that workbook
            Set wsDest = wb.ActiveSheet
        End If
    Next wb

    'Check if both a source and destination were assigned
    If wsSource Is Nothing Then
        MsgBox "ERROR - Unable to find valid source workbook to copy data from"
        Exit Sub
    ElseIf wsDest Is Nothing Then
        MsgBox "ERROR - Unable to find valid destination workbook to paste data into"
        Exit Sub
    End If

    'The first dimension is for how many times you need to define source and dest ranges, the second dimension should always be 1 to 2
    Dim aFromTo(1 To 2, 1 To 2) As Range
    'Add source copy ranges here:                       'Add destination paste ranges here
    Set aFromTo(1, 1) = wsSource.Range("M7:R19"):       Set aFromTo(1, 2) = wsDest.Range("M7")
    Set aFromTo(2, 1) = wsSource.Range("S7:AT16"):      Set aFromTo(2, 2) = wsDest.Range("U7")
    'Set aFromTo(3, 1) = wsSource.Range("M21:R33"):      Set aFromTo(3, 2) = wsDest.Range("M21")    'Example of a third copy/paste range - Dim aFromTo(1 to 3, 1 to 2)
    'Set aFromTo(4, 1) = wsSource.Range("S21:AT30"):     Set aFromTo(4, 2) = wsDest.Range("U21")    'Example of a fourth copy/paste range - Dim aFromTo(1 to 4, 1 to 2)

    'This will loop through the array of specified FromTo ranges and will ensure that only values are brought over
    Dim i As Long
    For i = LBound(aFromTo, 1) To UBound(aFromTo, 1)
        aFromTo(i, 2).Resize(aFromTo(i, 1).Rows.Count, aFromTo(i, 1).Columns.Count).Value = aFromTo(i, 1).Value
    Next i

End Sub
antwoordde op 14/01/2020 om 00:49
bron van user

Cookies help us deliver our services. By using our services, you agree to our use of cookies. Learn more